How to turn url text into actual clickable URLs is easy with the Linkify function.

When creating user interface websites, you want to allow users to easily add URLs to other websites. This can be done with [Linkify] in Classic ASP. Just wrap your requested form element in Linkify () and let the script do all the work for you.

You must have the link formatted with http:// or https:// at the beginning, or the link will not be created.

[Function.asp]

CFFCS | CarrzSynEdit: | ASP/VBScript

Function Linkify(Text)
    Dim regEx, Match, Matches, patternURLs, patternAnchors, lCount, anchorCount, replacements
    patternURLs = "((http|ftp|https)(:\/\/[\w\-_]+)((\.[\w\-_]+)+)([\w\-\.,@?^=%&:/~\+#]*[\w\-\@?^=%&/~\+#])?)"
    patternAnchors = "<a[^>]*?>.*?</a>"

    Set replacements=Server.CreateObject("Scripting.Dictionary")

    ' Create the regular expression.

    Set regEx = New RegExp
    regEx.Pattern = patternAnchors
    regEx.IgnoreCase = True
    regEx.Global = True

    ' Do the search for anchors.

    Set Matches = regEx.Execute(Text)

    lCount = 0

    ' Iterate through the existing anchors and replace with a placeholder

    For Each Match in Matches
      key = "<#" & lCount & "#>"
      replacements.Add key, Match.Value
      Text = Replace(Text,Cstr(Match.Value),key)
      lCount = lCount+1
    Next

    anchorCount = lCount

    'We now search for URLs

    regEx.Pattern = patternURLs

    ' create anchors from URLs

    Text = regEx.Replace(Text, "<a href=""$1"">$1</a>")

    ' put back the originally existing anchors

    For lCount = 0 To anchorCount-1
        key = "<#" & lCount & "#>"
        Text = Replace(Text,key, replacements.Item(key))
    Next

    Linkify = Text

End Function
%>

You must provide the http:// or https:// before the URL string for it to be processed.

[ASP Linkify Wrap]

CFFCS | CarrzSynEdit: | ASP/VBScript

<%=Linkify(request.Form("MyText1"))%>